PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
PREFIX dct:        <http://purl.org/dc/terms/>
PREFIX dbo:        <http://dbpedia.org/ontology/> 
PREFIX schema:     <https://schema.org/> 
PREFIX geo:        <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX xsd:        <http://www.w3.org/2001/XMLSchema#> 
PREFIX dh:         <https://w3id.org/atomgraph/linkeddatahub/document-hierarchy#>
PREFIX sioc:       <http://rdfs.org/sioc/ns#>

CONSTRUCT
{
    GRAPH ?item
    {
        ?item a dh:Item ;
            sioc:has_container ?container ;
            dh:slug ?id ;
            dct:title ?name ;
            foaf:primaryTopic ?bicyleParking .

        ?bicyleParking a ?type ;
            geo:lat ?lat ;
            geo:long ?long ;
            dct:title ?name ;
            dbo:city ?city ;
            schema:streetAddress ?address ;
            schema:maximumAttendeeCapacity ?spaces ;
            dct:identifier ?id .
    }
}
WHERE
{
    ?bicyleParking_row <#FID> ?id ;
        <#lat> ?lat_string ;
        <#long> ?long_string . 

    OPTIONAL 
    { ?bicyleParking_row <#name> ?name }
    OPTIONAL 
    { ?bicyleParking_row <#bydel> ?city }
    OPTIONAL 
    { ?bicyleParking_row <#vejnavn> ?address }
    OPTIONAL 
    { ?bicyleParking_row <#antal_pladser> ?spaces_string }

    BIND(uri(concat(str($base), "bicycle-parkings/")) AS ?container)
    BIND(uri(concat(str($base), "ns#BicycleParking")) AS ?type)
    BIND(uri(concat(str(?container), encode_for_uri(?id), "/")) AS ?item)
    BIND(uri(concat(str(?item), "#this")) AS ?bicyleParking)
    BIND(xsd:float(?lat_string) AS ?lat)
    BIND(xsd:float(?long_string) AS ?long)
    BIND(xsd:integer(?spaces_string) AS ?spaces)
}