PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
PREFIX dct:        <http://purl.org/dc/terms/>
PREFIX schema:     <https://schema.org/> 
PREFIX geo:        <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX xsd:        <http://www.w3.org/2001/XMLSchema#> 
PREFIX dh:         <https://w3id.org/atomgraph/linkeddatahub/document-hierarchy#>
PREFIX sioc:       <http://rdfs.org/sioc/ns#>

CONSTRUCT
{
    GRAPH ?item
    {
        ?item a dh:Item ;
            sioc:has_container ?container ;
            dh:slug ?id ;
            dct:title ?name ;
            foaf:primaryTopic ?sportCenter .

        ?sportCenter a ?type ;
            geo:lat ?lat ;
            geo:long ?long ;
            dct:title ?name ;
            schema:streetAddress ?address ;
            schema:postalCode ?postcode ;
            foaf:mbox ?email ;
            foaf:page ?link ;
            dct:identifier ?id .
    }
}
WHERE
{
    ?sportCenter_row <#FID> ?id ;
        <#name> ?name ;
        <#address> ?address ;
        <#lat> ?lat_string ;
        <#postcode> ?postcode ;
        <#long> ?long_string .

    OPTIONAL {
        ?sportCenter_row <#email> ?emailString
        BIND (URI(CONCAT(STR(<mailto:>), ?emailString)) AS ?email)
    }
    OPTIONAL {
        ?sportCenter_row <#link> ?linkString
        BIND (URI(?linkString) AS ?link) 
    }

    BIND(uri(concat(str($base), "sports-centers/")) AS ?container)
    BIND(uri(concat(str($base), "ns#SportsCenter")) AS ?type)
    BIND(uri(concat(str(?container), encode_for_uri(?id), "/")) AS ?item)
    BIND(uri(concat(str(?item), "#this")) AS ?sportCenter)
    BIND(xsd:float(?lat_string) AS ?lat)
    BIND(xsd:float(?long_string) AS ?long)
}